///
module phphelpers;

import std..string;
import std.exception;
import std.conv;

import std.variant;

Variant phpUnserialize(ref string text) {
	Variant v;
	if(text.length == 0)
		return v;

	auto colon = text.indexOf(":");
	enforce(colon != -1);

	string type = text[0 .. colon];
	text = text[colon + 1 .. $];

	switch(type) {
		default: assert(0);
		case "a":
			// PHP arrays are always AA. While it sometimes
			// uses int keys, I'm using strings here
			colon = text.indexOf(":");
			enforce(colon != -1);
			auto leng = to!int(text[0 .. colon]);
			text = text[colon + 1 .. $];
			enforce(text[0] == '{');

			text = text[1 .. $];

			Variant[string] aa;
			for(int a = 0; a < leng; a++) {
				// first is key, then is value
				auto key = phpUnserialize(text);
				auto value = phpUnserialize(text);

				aa[key.coerce!string] = value;
			}

			v = aa;

			enforce(text[0] == '}', text[0 .. $]);
			text = text[1 .. $];
		break;
		case "i":
			auto semicolon = text.indexOf(";");
			enforce(semicolon != -1);
			auto number = to!int(text[0 .. semicolon]);
			text = text[semicolon + 1 .. $];
			v = number;
		break;
		case "s":
			colon = text.indexOf(":");
			enforce(colon != -1);
			auto leng = to!int(text[0 .. colon]);
			text = text[colon + 1 .. $];
			enforce(text[0] == '"');

			string s = text[1 .. 1 + leng];
			text = text[1 + leng .. $];
			enforce(text[0..2] == `";`);

			text = text[2 .. $];

			v = s;
		break;
	}

	return v;
}

// convenience function so you don't have to pass a ref input
Variant unserialize(in string phptext) {
	string s = phptext;
	return phpUnserialize(s);
}